gor

gor.awk (5062B)

---

 BEGIN {
 	#  $1 Book name
 	#  $2 Book abbreviation
 	#  $3 Book number
 	#  $4 Stephanus page
 	#  $5 Section (1=a, 2=b, 3=c, 4=d, 5=e)
 	#  $6 Text
 	FS = "\t"
 
 	MAX_WIDTH = 80
 	if (ENVIRON["GOR_MAX_WIDTH"] ~ /^[0-9]+$/) {
 		if (int(ENVIRON["GOR_MAX_WIDTH"]) < MAX_WIDTH) {
 			MAX_WIDTH = int(ENVIRON["GOR_MAX_WIDTH"])
 		}
 	}
 
 	split("a,b,c,d,e", letters, ",")
 
 	if (cmd == "ref") {
 		mode = parseref(ref, p)
 		p["book"] = cleanbook(p["book"])
 	}
 }
 
 cmd == "list" {
 	if (!($2 in seen_books)) {
 		printf("%s (%s)\n", $1, $2)
 		seen_books[$2] = 1
 	}
 }
 
 function letterval(c) {
 	if (c == "a") return 1
 	if (c == "b") return 2
 	if (c == "c") return 3
 	if (c == "d") return 4
 	if (c == "e") return 5
 	return 0
 }
 
 function parseref(ref, arr) {
 	# Stephanus reference formats:
 	# 1. <book>
 	# 2. <book> <page>           (e.g., Gor 447)
 	# 3. <book> <page><letter>   (e.g., Gor 447a)
 	# 4. <book> <page>-<page>    (e.g., Gor 447-449)
 	# 5. <book> <page><l>-<page><l>  (e.g., Gor 447a-449c)
 	# 6. <book> <page><l>-<l>    (e.g., Gor 447a-c)
 	# 7. /<search>
 	# 8. <book>/<search>
 	# 9. <book> <page>/<search>
 
 	if (match(ref, "^[1-9]?[a-zA-Z ]+")) {
 		arr["book"] = substr(ref, 1, RLENGTH)
 		ref = substr(ref, RLENGTH + 1)
 	} else if (match(ref, "^/")) {
 		arr["search"] = substr(ref, 2)
 		return "search"
 	} else {
 		return "unknown"
 	}
 
 	# Parse optional page number
 	if (match(ref, "^:?[0-9]+")) {
 		if (sub("^:", "", ref)) {
 			arr["chapter"] = int(substr(ref, 1, RLENGTH - 1))
 			ref = substr(ref, RLENGTH)
 		} else {
 			arr["chapter"] = int(substr(ref, 1, RLENGTH))
 			ref = substr(ref, RLENGTH + 1)
 		}
 	} else if (match(ref, "^/")) {
 		arr["search"] = substr(ref, 2)
 		return "search"
 	} else if (ref == "") {
 		return "exact"
 	} else {
 		return "unknown"
 	}
 
 	# Parse optional letter (a-e)
 	if (match(ref, "^[a-e]")) {
 		arr["verse"] = letterval(substr(ref, 1, 1))
 		ref = substr(ref, 2)
 	} else if (match(ref, "^-[0-9]+")) {
 		# page-page range (no letter)
 		arr["chapter_end"] = int(substr(ref, 2))
 		return "range"
 	} else if (match(ref, "^/")) {
 		arr["search"] = substr(ref, 2)
 		return "search"
 	} else if (ref == "") {
 		return "exact"
 	} else {
 		return "unknown"
 	}
 
 	# After letter, check for range
 	if (match(ref, "^-[0-9]+[a-e]$")) {
 		# page-letter to page-letter range
 		r = substr(ref, 2)
 		arr["chapter_end"] = int(substr(r, 1, length(r) - 1))
 		arr["verse_end"] = letterval(substr(r, length(r), 1))
 		return "range_ext"
 	} else if (match(ref, "^-[a-e]$")) {
 		# same-page letter range (e.g., 447a-c)
 		arr["chapter_end"] = arr["chapter"]
 		arr["verse_end"] = letterval(substr(ref, 2, 1))
 		return "range"
 	} else if (match(ref, "^-[0-9]+$")) {
 		# letter to page range (e.g., 447a-449)
 		arr["chapter_end"] = int(substr(ref, 2))
 		return "range"
 	} else if (ref == "") {
 		return "exact"
 	} else {
 		return "unknown"
 	}
 }
 
 function cleanbook(book) {
 	book = tolower(book)
 	gsub(" +", "", book)
 	return book
 }
 
 function bookmatches(book, bookabbr, query) {
 	book = cleanbook(book)
 	if (book == query) {
 		return book
 	}
 
 	bookabbr = cleanbook(bookabbr)
 	if (bookabbr == query) {
 		return book
 	}
 
 	if (substr(book, 1, length(query)) == query) {
 		return book
 	}
 }
 
 function printverse(verse,    word_count, characters_printed) {
 	if (ENVIRON["GOR_NOLINEWRAP"] != "" && ENVIRON["GOR_NOLINEWRAP"] != "0") {
 		printf("%s\n", verse)
 		return
 	}
 
 	word_count = split(verse, words, " ")
 	for (i = 1; i <= word_count; i++) {
 		if (characters_printed + length(words[i]) + (characters_printed > 0 ? 1 : 0) > MAX_WIDTH - 8) {
 			printf("\n\t")
 			characters_printed = 0
 		}
 		if (characters_printed > 0) {
 			printf(" ")
 			characters_printed++
 		}
 		printf("%s", words[i])
 		characters_printed += length(words[i])
 	}
 	printf("\n")
 }
 
 function processline() {
 	if (last_book_printed != $2) {
 		print $1
 		last_book_printed = $2
 	}
 
 	printf("%d%s\t", $4, letters[$5])
 	printverse($6)
 	outputted_records++
 }
 
 cmd == "ref" && mode == "exact" && bookmatches($1, $2, p["book"]) && (p["chapter"] == "" || $4 == p["chapter"]) && (p["verse"] == "" || $5 == p["verse"]) {
 	processline()
 }
 
 cmd == "ref" && mode == "range" && bookmatches($1, $2, p["book"]) && ((p["chapter_end"] == "" && $4 == p["chapter"]) || ($4 >= p["chapter"] && $4 <= p["chapter_end"])) && (p["verse"] == "" || $5 >= p["verse"]) && (p["verse_end"] == "" || $5 <= p["verse_end"]) {
 	processline()
 }
 
 cmd == "ref" && mode == "range_ext" && bookmatches($1, $2, p["book"]) && (($4 == p["chapter"] && $5 >= p["verse"] && p["chapter"] != p["chapter_end"]) || ($4 > p["chapter"] && $4 < p["chapter_end"]) || ($4 == p["chapter_end"] && $5 <= p["verse_end"] && p["chapter"] != p["chapter_end"]) || (p["chapter"] == p["chapter_end"] && $4 == p["chapter"] && $5 >= p["verse"] && $5 <= p["verse_end"])) {
 	processline()
 }
 
 cmd == "ref" && mode == "search" && (p["book"] == "" || bookmatches($1, $2, p["book"])) && (p["chapter"] == "" || $4 == p["chapter"]) && match(tolower($6), tolower(p["search"])) {
 	processline()
 }
 
 END {
 	if (cmd == "ref" && outputted_records == 0) {
 		print "Unknown reference: " ref
 	}
 }